Update #0 - First Release

sources/resources/assets/eagler/glsl/accel_font.fsh

@@ -0,0 +1,34 @@
+#line 2
+
+/*
+ * Copyright (c) 2022 LAX1DUDE. All Rights Reserved.
+ * 
+ * WITH THE EXCEPTION OF PATCH FILES, MINIFIED JAVASCRIPT, AND ALL FILES
+ * NORMALLY FOUND IN AN UNMODIFIED MINECRAFT RESOURCE PACK, YOU ARE NOT ALLOWED
+ * TO SHARE, DISTRIBUTE, OR REPURPOSE ANY FILE USED BY OR PRODUCED BY THE
+ * SOFTWARE IN THIS REPOSITORY WITHOUT PRIOR PERMISSION FROM THE PROJECT AUTHOR.
+ * 
+ * NOT FOR COMMERCIAL OR MALICIOUS USE
+ * 
+ * (please read the 'LICENSE' file this repo's root directory for more info) 
+ * 
+ */
+
+precision lowp int;
+precision highp float;
+precision lowp sampler2D;
+
+in vec2 v_texCoord2f;
+in vec4 v_color4f;
+
+out vec4 output4f;
+
+uniform sampler2D u_inputTexture;
+uniform vec4 u_colorBias4f;
+
+void main() {
+	output4f = texture(u_inputTexture, v_texCoord2f) * v_color4f + u_colorBias4f;
+	if(output4f.a < 0.004) {
+		discard;
+	}
+}

sources/resources/assets/eagler/glsl/accel_font.vsh

@@ -0,0 +1,51 @@
+#line 2
+
+/*
+ * Copyright (c) 2022 LAX1DUDE. All Rights Reserved.
+ * 
+ * WITH THE EXCEPTION OF PATCH FILES, MINIFIED JAVASCRIPT, AND ALL FILES
+ * NORMALLY FOUND IN AN UNMODIFIED MINECRAFT RESOURCE PACK, YOU ARE NOT ALLOWED
+ * TO SHARE, DISTRIBUTE, OR REPURPOSE ANY FILE USED BY OR PRODUCED BY THE
+ * SOFTWARE IN THIS REPOSITORY WITHOUT PRIOR PERMISSION FROM THE PROJECT AUTHOR.
+ * 
+ * NOT FOR COMMERCIAL OR MALICIOUS USE
+ * 
+ * (please read the 'LICENSE' file this repo's root directory for more info) 
+ * 
+ */
+
+precision lowp int;
+precision highp float;
+precision lowp sampler2D;
+
+in vec3 a_position3f;
+
+in vec2 c_position2i;
+in vec2 c_coords2i;
+in vec4 c_color4f;
+
+out vec2 v_texCoord2f;
+out vec4 v_color4f;
+
+uniform mat4 u_matrixTransform;
+uniform vec2 u_charSize2f;
+uniform vec2 u_charCoordSize2f;
+uniform vec4 u_color4f;
+
+void main() {
+	v_color4f = c_color4f.bgra;
+	float shadowBit = a_position3f.z;
+	float boldBit = shadowBit >= 0.5 ? 1.0 : 0.0;
+	shadowBit -= boldBit * 0.5;
+	v_color4f.rgb *= (1.0 - shadowBit * 3.0);
+	v_texCoord2f = (c_coords2i + a_position3f.xy) * u_charCoordSize2f;
+	vec2 pos2d = c_position2i + vec2(shadowBit * 4.0);
+	pos2d += a_position3f.xy * u_charSize2f;
+	pos2d.x += boldBit;
+	float italicBit = v_color4f.a >= 0.5 ? 2.0 : 0.0;
+	v_color4f.a -= italicBit * 0.25;
+	pos2d.x -= (a_position3f.y - 0.5) * italicBit;
+	v_color4f.a *= 2.0;
+	v_color4f *= u_color4f;
+	gl_Position = u_matrixTransform * vec4(pos2d, 0.0, 1.0);
+}

sources/resources/assets/eagler/glsl/accel_particle.fsh

@@ -0,0 +1,33 @@
+#line 2
+
+/*
+ * Copyright (c) 2022 LAX1DUDE. All Rights Reserved.
+ * 
+ * WITH THE EXCEPTION OF PATCH FILES, MINIFIED JAVASCRIPT, AND ALL FILES
+ * NORMALLY FOUND IN AN UNMODIFIED MINECRAFT RESOURCE PACK, YOU ARE NOT ALLOWED
+ * TO SHARE, DISTRIBUTE, OR REPURPOSE ANY FILE USED BY OR PRODUCED BY THE
+ * SOFTWARE IN THIS REPOSITORY WITHOUT PRIOR PERMISSION FROM THE PROJECT AUTHOR.
+ * 
+ * NOT FOR COMMERCIAL OR MALICIOUS USE
+ * 
+ * (please read the 'LICENSE' file this repo's root directory for more info) 
+ * 
+ */
+
+precision lowp int;
+precision highp float;
+precision highp sampler2D;
+
+in vec2 v_texCoord2f;
+in vec4 v_color4f;
+
+out vec4 output4f;
+
+uniform sampler2D u_inputTexture;
+
+void main() {
+	output4f = texture(u_inputTexture, v_texCoord2f) * v_color4f;
+	if(output4f.a < 0.004) {
+		discard;
+	}
+}

sources/resources/assets/eagler/glsl/accel_particle.vsh

@@ -0,0 +1,64 @@
+#line 2
+
+/*
+ * Copyright (c) 2022 LAX1DUDE. All Rights Reserved.
+ * 
+ * WITH THE EXCEPTION OF PATCH FILES, MINIFIED JAVASCRIPT, AND ALL FILES
+ * NORMALLY FOUND IN AN UNMODIFIED MINECRAFT RESOURCE PACK, YOU ARE NOT ALLOWED
+ * TO SHARE, DISTRIBUTE, OR REPURPOSE ANY FILE USED BY OR PRODUCED BY THE
+ * SOFTWARE IN THIS REPOSITORY WITHOUT PRIOR PERMISSION FROM THE PROJECT AUTHOR.
+ * 
+ * NOT FOR COMMERCIAL OR MALICIOUS USE
+ * 
+ * (please read the 'LICENSE' file this repo's root directory for more info) 
+ * 
+ */
+
+precision lowp int;
+precision highp float;
+precision lowp sampler2D;
+
+in vec2 a_position2f;
+
+in vec3 p_position3f;
+in vec2 p_texCoords2i;
+in vec2 p_lightMap2f;
+in vec2 p_particleSize_texCoordsSize_2i;
+in vec4 p_color4f;
+
+out vec2 v_texCoord2f;
+out vec4 v_color4f;
+
+uniform mat4 u_matrixTransform;
+uniform vec3 u_texCoordSize2f_particleSize1f;
+uniform vec4 u_transformParam_1_2_3_4_f;
+uniform float u_transformParam_5_f;
+uniform vec4 u_color4f;
+
+uniform sampler2D u_lightmapTexture;
+
+void main() {
+	v_color4f = u_color4f * p_color4f.bgra * texture(u_lightmapTexture, p_lightMap2f);
+
+	vec2 tex2f = a_position2f * 0.5 + 0.5;
+	tex2f.y = 1.0 - tex2f.y;
+	tex2f = p_texCoords2i + tex2f * p_particleSize_texCoordsSize_2i.y;
+	v_texCoord2f = tex2f * u_texCoordSize2f_particleSize1f.xy;
+
+	float particleSize = u_texCoordSize2f_particleSize1f.z * p_particleSize_texCoordsSize_2i.x;
+
+	float f1 = u_transformParam_1_2_3_4_f.x;
+	float f2 = u_transformParam_1_2_3_4_f.y;
+	float f3 = u_transformParam_1_2_3_4_f.z;
+	float f4 = u_transformParam_1_2_3_4_f.w;
+	float f5 = u_transformParam_5_f;
+
+	vec3 pos3f = p_position3f;
+	pos3f.x += f1 * particleSize * a_position2f.x;
+	pos3f.x += f4 * particleSize * a_position2f.y;
+	pos3f.y += f2 * particleSize * a_position2f.y;
+	pos3f.z += f3 * particleSize * a_position2f.x;
+	pos3f.z += f5 * particleSize * a_position2f.y;
+
+	gl_Position = u_matrixTransform * vec4(pos3f, 1.0);
+}

sources/resources/assets/eagler/glsl/core.fsh

@@ -0,0 +1,180 @@
+#line 2
+
+/*
+ * Copyright (c) 2022 LAX1DUDE. All Rights Reserved.
+ * 
+ * WITH THE EXCEPTION OF PATCH FILES, MINIFIED JAVASCRIPT, AND ALL FILES
+ * NORMALLY FOUND IN AN UNMODIFIED MINECRAFT RESOURCE PACK, YOU ARE NOT ALLOWED
+ * TO SHARE, DISTRIBUTE, OR REPURPOSE ANY FILE USED BY OR PRODUCED BY THE
+ * SOFTWARE IN THIS REPOSITORY WITHOUT PRIOR PERMISSION FROM THE PROJECT AUTHOR.
+ * 
+ * NOT FOR COMMERCIAL OR MALICIOUS USE
+ * 
+ * (please read the 'LICENSE' file this repo's root directory for more info) 
+ * 
+ */
+
+#if defined(COMPILE_ENABLE_TEX_GEN) || defined(COMPILE_ENABLE_FOG)
+in vec4 v_position4f;
+#endif
+
+#ifdef COMPILE_TEXTURE_ATTRIB
+in vec2 v_texture2f;
+#endif
+
+uniform vec4 u_color4f;
+
+#ifdef COMPILE_BLEND_ADD
+uniform vec4 u_colorBlendSrc4f;
+uniform vec4 u_colorBlendAdd4f;
+#endif
+
+#ifdef COMPILE_COLOR_ATTRIB
+in vec4 v_color4f;
+#endif
+
+#ifdef COMPILE_NORMAL_ATTRIB
+in vec3 v_normal3f;
+#endif
+
+#ifdef COMPILE_LIGHTMAP_ATTRIB
+in vec2 v_lightmap2f;
+#endif
+
+#ifdef COMPILE_ENABLE_TEXTURE2D
+uniform sampler2D u_samplerTexture;
+#if !defined(COMPILE_TEXTURE_ATTRIB) && !defined(COMPILE_ENABLE_TEX_GEN)
+uniform vec2 u_textureCoords01;
+#endif
+#endif
+
+#ifdef COMPILE_ENABLE_LIGHTMAP
+uniform sampler2D u_samplerLightmap;
+#ifndef COMPILE_LIGHTMAP_ATTRIB
+uniform vec2 u_textureCoords02;
+#endif
+#endif
+
+#ifdef COMPILE_ENABLE_ALPHA_TEST
+uniform float u_alphaTestRef1f;
+#endif
+
+#ifdef COMPILE_ENABLE_MC_LIGHTING
+uniform int u_lightsEnabled1i;
+uniform vec4 u_lightsDirections4fv[4];
+uniform vec3 u_lightsAmbient3f;
+#ifndef COMPILE_NORMAL_ATTRIB
+uniform vec3 u_uniformNormal3f;
+#endif
+#endif
+
+#ifdef COMPILE_ENABLE_FOG
+uniform vec4 u_fogParameters4f;
+uniform vec4 u_fogColor4f;
+#endif
+
+#ifdef COMPILE_ENABLE_TEX_GEN
+in vec3 v_objectPosition3f;
+uniform ivec4 u_texGenPlane4i;
+uniform vec4 u_texGenS4f;
+uniform vec4 u_texGenT4f;
+uniform vec4 u_texGenR4f;
+uniform vec4 u_texGenQ4f;
+uniform mat4 u_textureMat4f01;
+#endif
+
+#ifdef COMPILE_ENABLE_ANISOTROPIC_FIX
+uniform vec2 u_textureAnisotropicFix;
+#endif
+
+out vec4 output4f;
+
+void main() {
+
+#ifdef COMPILE_COLOR_ATTRIB
+	vec4 color = v_color4f * u_color4f;
+#else
+	vec4 color = u_color4f;
+#endif
+	
+#ifdef COMPILE_ENABLE_TEX_GEN
+	vec4 texGenVector;
+	
+	vec4 texGenPosSrc[2];
+	texGenPosSrc[0] = vec4(v_objectPosition3f, 1.0);
+	texGenPosSrc[1] = v_position4f;
+	
+	texGenVector.x = dot(texGenPosSrc[u_texGenPlane4i.x], u_texGenS4f);
+	texGenVector.y = dot(texGenPosSrc[u_texGenPlane4i.y], u_texGenT4f);
+	texGenVector.z = dot(texGenPosSrc[u_texGenPlane4i.z], u_texGenR4f);
+	texGenVector.w = dot(texGenPosSrc[u_texGenPlane4i.w], u_texGenQ4f);
+	
+	texGenVector = u_textureMat4f01 * texGenVector;
+	color *= texture(u_samplerTexture, texGenVector.xy / texGenVector.w);
+	
+#ifdef COMPILE_ENABLE_ALPHA_TEST
+	if(color.a < u_alphaTestRef1f) discard;
+#endif
+
+#else
+
+#ifdef COMPILE_ENABLE_TEXTURE2D
+#ifdef COMPILE_TEXTURE_ATTRIB
+#ifdef COMPILE_ENABLE_ANISOTROPIC_FIX
+	// d3d11 doesn't support GL_NEAREST upscaling with anisotropic
+	// filtering enabled, so it needs this stupid fix to 'work'
+	vec2 uv = floor(v_texture2f * u_textureAnisotropicFix) + 0.5;
+	color *= texture(u_samplerTexture, uv / u_textureAnisotropicFix);
+#else
+	color *= texture(u_samplerTexture, v_texture2f);
+#endif
+#else
+	color *= texture(u_samplerTexture, u_textureCoords01);
+#endif
+#endif
+
+#ifdef COMPILE_ENABLE_LIGHTMAP
+#ifdef COMPILE_LIGHTMAP_ATTRIB
+	color *= texture(u_samplerLightmap, v_lightmap2f);
+#else
+	color *= texture(u_samplerLightmap, u_textureCoords02);
+#endif
+#endif
+
+#ifdef COMPILE_ENABLE_ALPHA_TEST
+	if(color.a < u_alphaTestRef1f) discard;
+#endif
+
+#endif
+
+#ifdef COMPILE_ENABLE_MC_LIGHTING
+#ifdef COMPILE_NORMAL_ATTRIB
+	vec3 normal = normalize(v_normal3f);
+#else
+	vec3 normal = u_uniformNormal3f;
+#endif
+	float diffuse = 0.0;
+	for(int i = 0; i < u_lightsEnabled1i; ++i) {
+		vec4 light = u_lightsDirections4fv[i];
+		diffuse += max(dot(light.xyz, normal), 0.0) * light.w;
+	}
+	color.rgb *= min(u_lightsAmbient3f + vec3(diffuse), 1.0);
+#endif
+
+#ifdef COMPILE_BLEND_ADD
+	color.rgba = color.rgba * u_colorBlendSrc4f + u_colorBlendAdd4f;
+#endif
+
+#ifdef COMPILE_ENABLE_FOG
+	vec3 fogPos = v_position4f.xyz / v_position4f.w;
+	float dist = sqrt(dot(fogPos, fogPos));
+	float fogDensity = u_fogParameters4f.y;
+	float fogStart = u_fogParameters4f.z;
+	float fogEnd = u_fogParameters4f.w;
+	float f = u_fogParameters4f.x > 0.0 ? 1.0 - pow(2.718, -(fogDensity * dist)) :
+		(dist - fogStart) / (fogEnd - fogStart);
+	color.rgb = mix(color.rgb, u_fogColor4f.rgb, clamp(f, 0.0, 1.0) * u_fogColor4f.a);
+#endif
+
+	output4f = color;
+}

sources/resources/assets/eagler/glsl/core.vsh

@@ -0,0 +1,103 @@
+#line 2
+
+/*
+ * Copyright (c) 2022 LAX1DUDE. All Rights Reserved.
+ * 
+ * WITH THE EXCEPTION OF PATCH FILES, MINIFIED JAVASCRIPT, AND ALL FILES
+ * NORMALLY FOUND IN AN UNMODIFIED MINECRAFT RESOURCE PACK, YOU ARE NOT ALLOWED
+ * TO SHARE, DISTRIBUTE, OR REPURPOSE ANY FILE USED BY OR PRODUCED BY THE
+ * SOFTWARE IN THIS REPOSITORY WITHOUT PRIOR PERMISSION FROM THE PROJECT AUTHOR.
+ * 
+ * NOT FOR COMMERCIAL OR MALICIOUS USE
+ * 
+ * (please read the 'LICENSE' file this repo's root directory for more info) 
+ * 
+ */
+
+in vec3 a_position3f;
+
+#if defined(COMPILE_ENABLE_TEX_GEN) || defined(COMPILE_ENABLE_FOG)
+#define _COMPILE_VARYING_POSITION
+#endif
+
+#ifdef _COMPILE_VARYING_POSITION
+out vec4 v_position4f;
+#endif
+
+#ifdef COMPILE_ENABLE_TEX_GEN
+out vec3 v_objectPosition3f;
+#endif
+
+#ifdef COMPILE_TEXTURE_ATTRIB
+in vec2 a_texture2f;
+out vec2 v_texture2f;
+uniform mat4 u_textureMat4f01;
+#endif
+
+#ifdef COMPILE_COLOR_ATTRIB
+in vec4 a_color4f;
+out vec4 v_color4f;
+#endif
+
+#ifdef COMPILE_NORMAL_ATTRIB
+in vec4 a_normal4f;
+out vec3 v_normal3f;
+#endif
+
+#ifdef COMPILE_LIGHTMAP_ATTRIB
+in vec2 a_lightmap2f;
+out vec2 v_lightmap2f;
+uniform mat4 u_textureMat4f02;
+#endif
+
+uniform mat4 u_modelviewMat4f;
+uniform mat4 u_projectionMat4f;
+
+void main() {
+	
+#ifdef COMPILE_ENABLE_TEX_GEN
+	v_objectPosition3f = a_position3f;
+#endif
+
+	vec4 pos = u_modelviewMat4f * vec4(a_position3f, 1.0);
+	
+#ifdef _COMPILE_VARYING_POSITION
+	v_position4f = pos;
+#endif
+
+#ifdef COMPILE_TEXTURE_ATTRIB
+	mat4x3 texMat4x3 = mat4x3(
+		u_textureMat4f01[0].xyw,
+		u_textureMat4f01[1].xyw,
+		u_textureMat4f01[2].xyw,
+		u_textureMat4f01[3].xyw
+	);
+	vec3 v_textureTmp3f = texMat4x3 * vec4(a_texture2f, 1.0, 1.0);
+	v_texture2f = v_textureTmp3f.xy / v_textureTmp3f.z;
+#endif
+	
+#ifdef COMPILE_COLOR_ATTRIB
+	v_color4f = a_color4f;
+#endif
+	
+#ifdef COMPILE_NORMAL_ATTRIB
+	v_normal3f = normalize(mat3(u_modelviewMat4f) * a_normal4f.xyz);
+#endif
+	
+#ifdef COMPILE_LIGHTMAP_ATTRIB
+#ifdef COMPILE_TEXTURE_ATTRIB
+	texMat4x3 = mat4x3(
+#else
+	mat4x3 texMat4x3 = mat4x3(
+#endif
+		u_textureMat4f02[0].xyw,
+		u_textureMat4f02[1].xyw,
+		u_textureMat4f02[2].xyw,
+		u_textureMat4f02[3].xyw
+	);
+	vec3 v_lightmapTmp3f = texMat4x3 * vec4(a_lightmap2f, 1.0, 1.0);
+	v_lightmap2f = v_lightmapTmp3f.xy / v_lightmapTmp3f.z;
+#endif
+
+	gl_Position = u_projectionMat4f * pos;
+}

sources/resources/assets/eagler/glsl/local.vsh

@@ -0,0 +1,28 @@
+#line 2
+
+/*
+ * Copyright (c) 2022 LAX1DUDE. All Rights Reserved.
+ * 
+ * WITH THE EXCEPTION OF PATCH FILES, MINIFIED JAVASCRIPT, AND ALL FILES
+ * NORMALLY FOUND IN AN UNMODIFIED MINECRAFT RESOURCE PACK, YOU ARE NOT ALLOWED
+ * TO SHARE, DISTRIBUTE, OR REPURPOSE ANY FILE USED BY OR PRODUCED BY THE
+ * SOFTWARE IN THIS REPOSITORY WITHOUT PRIOR PERMISSION FROM THE PROJECT AUTHOR.
+ * 
+ * NOT FOR COMMERCIAL OR MALICIOUS USE
+ * 
+ * (please read the 'LICENSE' file this repo's root directory for more info) 
+ * 
+ */
+
+precision lowp int;
+precision lowp float;
+precision lowp sampler2D;
+
+in vec2 a_position2f;
+
+out vec2 v_position2f;
+
+void main() {
+	v_position2f = a_position2f;
+	gl_Position = vec4(a_position2f * 2.0 - 1.0, 0.0, 1.0);
+}

sources/resources/assets/eagler/glsl/texture_mix.fsh

@@ -0,0 +1,35 @@
+#line 2
+
+/*
+ * Copyright (c) 2022 LAX1DUDE. All Rights Reserved.
+ * 
+ * WITH THE EXCEPTION OF PATCH FILES, MINIFIED JAVASCRIPT, AND ALL FILES
+ * NORMALLY FOUND IN AN UNMODIFIED MINECRAFT RESOURCE PACK, YOU ARE NOT ALLOWED
+ * TO SHARE, DISTRIBUTE, OR REPURPOSE ANY FILE USED BY OR PRODUCED BY THE
+ * SOFTWARE IN THIS REPOSITORY WITHOUT PRIOR PERMISSION FROM THE PROJECT AUTHOR.
+ * 
+ * NOT FOR COMMERCIAL OR MALICIOUS USE
+ * 
+ * (please read the 'LICENSE' file this repo's root directory for more info) 
+ * 
+ */
+
+precision lowp int;
+precision highp float;
+precision lowp sampler2D;
+
+in vec2 v_position2f;
+
+out vec4 output4f;
+
+uniform sampler2D u_inputTexture;
+uniform float u_textureLod1f;
+uniform vec4 u_blendFactor4f;
+uniform vec4 u_blendBias4f;
+uniform mat3 u_matrixTransform;
+
+void main() {
+	vec3 coords = u_matrixTransform * vec3(v_position2f, 1.0);
+	vec4 color4f = textureLod(u_inputTexture, coords.xy, u_textureLod1f);
+	output4f = color4f * u_blendFactor4f + u_blendBias4f;
+}